COMMENT !-----------------------------------------------------------------------------!
COMMENT ! EXAMPLE COPTIM INPUT - single minimum normal mode analysis of met-enkephalin! 
COMMENT ! Tested for r15589 of COPTIM (01/05/09)                                      !
COMMENT !                                                                             !
COMMENT ! To use you will need to change the paths indicated by 'CHANGE-->' to reflect!
COMMENT ! your installation of the group software.                                    !
COMMENT !-----------------------------------------------------------------------------!

COMMENT <KEYWORD SUMMARY>
COMMENT DEBUG : DEBUG included to give you more output to look at
COMMENT BFGSMIN 1D-6 : calls for an LBFGS minimisation until the root-mean-square gradient converges to 10^(-6)
COMMENT DUMPVECTOR ALLVECTORS MWVECTORS : Dump all (ALLVECTORS) mass-weighted (MWVECTORS) Hessian eigenvectors (the normal modes) to 
COMMENT                                   vector.dump with frequencies in cm-1. Also dump PDBs describing the per atoms and per residue 
COMMENT                                   displacement resulting from the action of these vectors.
COMMENT KTWN : Set kT in cm^(-1) to 212.67 corresponding to the temperature in the upper respiratory tract of humans. This is used to 
COMMENT        Boltzmann weight the atomic or residue displacements caused by thermally accessible normal modes (defined by frequency < kT)
COMMENT DUMPMODE 1 2 10 : Dump modes 1, 2 and 10 to individual PDB files for later visualisation
COMMENT DUMPSTRUCTURES : Specifies that final structures should be dumped for the runs into pdb and xyz formats
COMMENT STEPS 2000 : Do up to 2000 steps of optimisation
COMMENT CHARMMTYPE toph19_eef1_perm.inp param19_eef1_perm.inp : Specify the CHARMM topology and parameter files to use - also sets the type
COMMENT                                                         of CHARMM forcefield used to CHARMM19 (united atom)
COMMENT CHARMM :  Everything below the CHARMM line above is part of a CHARMM input file

DEBUG
BFGSMIN 1D-6
DUMPVECTOR ALLVECTORS MWVECTORS
KTWN 212.67 
DUMPMODE 1 2 10
DUMPSTRUCTURES
STEPS 2000
CHARMMTYPE toph19_eef1_perm.inp param19_eef1_perm.inp
CHARMM

! BOMLev sets the level of warnings what do not cause the program to exit. -5 = very lax
BOMLev -5

! PRNLEV sets the ammount of output you get from CHARMM. 0 = small
PRNLEV 0

! Read standard topology and parameter files
! CHANGE-->
set pardir "/home/csw34/svn/CHARMM31/toppar"
OPEN READ CARD UNIT 1 NAME @pardir/@top
READ RTF CARD UNIT 1
CLOSE UNIT 1

OPEN READ CARD UNIT 2 NAME @pardir/@par
READ PARAMETER CARD UNIT 2
CLOSE UNIT 2

! Generate the PSF for met-enk
READ SEQUence CARD
*
5
TYR GLY GLY PHE MET
GENErate FIRS NTER LAST CTER SETUp

OPEN UNIT 20 NAME input.crd READ CARD
READ COOR UNIT 20 CARD FREE
CLOSE UNIT 20

! Build the internal coordinate tables
IC FILL PRESERVE
IC PARAMETERS
IC PURGE
IC BUILD

! Set up the EEF1 solvent model
! CHANGE-->
eef1 setup temp 298.15 unit 93 name "/home/csw34/svn/CHARMM31/toppar/solvpar.inp"
update ctonnb 7. ctofnb 9. cutnb 15. group rdie
